﻿title   ZOBEX System Generation Program (20-Aug-81)
;########################################################;
;#                                                      #;
;#          ZOBEX SYSTEM GENERATION PROGRAM             #;
;#                                                      #;
;#======================================================#;
;#                                                      #;
;#  Written by: Frank MacLachlan                        #;
;#  Date:       20-Aug-81                               #;
;#  Revised:                                            #;
;#                                                      #;
;#  To assemble:                                        #;
;#      zasm zgen.aza                                   #;
;#                                                      #;
;#  To link:                                            #;
;#      l80 zgen,z80lib/s,zgen/n/e:start                #;
;#                                                      #;
;########################################################;


;########################################################;
;#              system definitions                      #;
;########################################################;


;       external references:


        global  dfcb,boot


;       Entry points:


        global  start           ; start of program


;       Address constants:


TBASE   equ     0100h           ; base of TPA
PBUF    equ     0900h           ; base of load image buffer


;       File Control Block offsets:


FCBN    equ     1               ; offset to name field
FCBNR   equ     32              ; offset to next record byte


;       Miscellaneous definitions:


WRALL   equ     0               ; write to allocated record
WRDIR   equ     1               ; write to directory record
WRUAL   equ     2               ; write to unallocated record


        list    off
*include stddefs.z80            ; library definition files
*maclib  stdmacs.z80            ; library macro routines
        list    on


;       DPB (Disk Parameter Block) structure definition:


        struct  0
SPT:    defs    2               ; sectors per track
BSH:    defs    1               ; block shift factor
BLM:    defs    1               ; block mask
EXM:    defs    1               ; extent mask
DSM:    defs    2               ; disk size - 1
DRM:    defs    2               ; maximum directory number
AL0:    defs    1               ; alloc 0
AL1:    defs    1               ; alloc 1
CKS:    defs    2               ; check size
OFF:    defs    2               ; track offset to group 0
OSS:    defs    1               ; number of OS sectors
FST:    defs    1               ; first sector on track
BMK:    defs    1               ; buffer mask
        endm


;       Macro definitions:


reboot  macro
        rst     00h             ;; so long!
        endm




;########################################################;
;#                   MAIN PROGRAM                       #;
;########################################################;


start:  tstz80                  ; CPU must be Z-80
        ld      sp,stktop
        print   'ZOBEX Sysgen Program V1.00  (Created 20-Aug-81)',CR,LF
        call    getfil          ; chk if file spec present, read if yes
        call    c,getsys        ; if no file spec then get system if req'd
more:   call    putsys          ; put system if req'd
        br      nc,more         ; do this again
        jp      boot            ; reboot




;########################################################;
;#                 SUPPORT SUBROUTINES                  #;
;########################################################;


getfil: ; Check CP/M default buffer for valid file spec, load file
        ; if valid.
        ;
        ; Entry:   nil
        ; Exit:    CY = 0 if file was read into PBUF, 1 if not
        ;
        ld      a,(dfcb+FCBN)
        cp      a,' '
        scf
        ret     z               ; no file spec given
        system  OPEN,dfcb       ; try to open the file
        inc     a
        br      nz,getf0
        print   BEL,CR,LF,'?Can''t open input file'
        reboot
        ;
getf0:  clra
        ld      (dfcb+FCBNR),a  ; next record := 0
        system  DMASET,PBUF     ; set dma adr
        ld      b,[PBUF-TBASE]/128  ; B := number of records to skip
getf2:  save    bc
        system  READ,DFCB       ; read next sector
        restor  bc
        tbr     a,z,getf4
        print   BEL,CR,LF,'?Bad input file format'
        reboot
        ;
getf4:  djnz    getf2           ; more records to skip
        ld      de,PBUF
getf6:  save    de
        system  DMASET          ; set next dma adr
        system  READ,DFCB
        restor  hl
        tret    a,nz            ; exit if end of file
        ld      de,128
        add     hl,de
        ex      de,hl           ; advance dma adr
        br      getf6




getsys: ; Ask if user wants to get system, do so if yes
        ;
        print   CR,LF,'Source drive name (or RETURN to skip) '
        call    getdrv          ; get drive number
        ret     c               ; exit if CR entered
        ld      (drive),a       ; save drive number
        call    select          ; select the drive
        tst     hl
        br      nz,gsys2        ; seems to be there
        print   BEL,CR,LF,'?Bad drive number'
        br      getsys          ; try again
        ;
gsys2:  print   CR,LF,'Source on drive '
        call    prndrv
        print   ', then type RETURN '
        call    getch
        cp      a,CR
        jp      ne,getsys
        call    gparms          ; select disk, get parms
        ld      hl,PBUF
        ld      (dmaadr),hl     ; dmaadr := PBUF
gsys4:  ld      hl,count
        tbr     (hl),z,gsys6    ; done if count == 0
        dec     (hl)            ; count := count - 1
        call    setdma          ; set dma adr
        call    settrk          ; set track adr
        call    setsec          ; set sector adr
        cbios   BOSRED          ; read next sector
        tcall   a,nz,dskerr     ; error msg if read error
        ret     c               ; exit if user wants out
        call    bmpdma          ; bump dma adr
        call    bmpdsk          ; increment disk adr (sector, track)
        br      gsys4
        ;
gsys6:  print   CR,LF,'System loaded'
        ret




putsys: ; Ask if user wants to put system, do so if yes
        ;
        print   CR,LF,'Destination drive name (or RETURN to reboot) '
        call    getdrv          ; get drive number
        ret     c               ; exit if CR entered
        ld      (drive),a       ; save drive number
        call    select          ; select the drive
        tst     hl
        br      nz,psys2        ; seems to be there
        print   BEL,CR,LF,'?Bad drive number'
        br      putsys          ; try again
        ;
psys2:  print   CR,LF,'Destination on drive '
        call    prndrv
        print   ', then type RETURN '
        call    getch
        cp      a,CR
        jp      ne,putsys
        call    gparms          ; select disk, get parms
        ld      hl,PBUF
        ld      (dmaadr),hl     ; dmaadr := PBUF
psys4:  ld      hl,count
        tbr     (hl),z,psys6    ; done if count == 0
        dec     (hl)            ; count := count - 1
        call    setdma          ; set dma adr
        call    settrk          ; set track adr
        call    setsec          ; set sector adr
        cbios   BOSWRT,WRUAL    ; write next sector
        tcall   a,nz,dskerr     ; error msg if write error
        ret     c               ; exit if user wants out
        call    bmpdma          ; bump dma adr
        call    bmpdsk          ; increment disk adr (sector, track)
        br      psys4
        ;
psys6:  print   CR,LF,'System written'
        ret




gparms: ; Get parameters for system read/write operations.
        ;
        ; Entry:   (drive)  = drive to select
        ; Exit:    (count)  = number of system sectors,
        ;          (track)  = starting track adr,
        ;          (sec)    = current sector adr,
        ;          (ssec)   = starting sector adr,
        ;          (esec)   = ending sector adr
        ;
        cbios   BOSSEL,(drive)  ; select drive
        save    hl
        ld      e,(hl)
        inc     hl
        ld      d,(hl)
        ld      bc,0
        cbios   BOSXLT
        ld      a,l             ; A := starting sector number
        ld      (ssec),a        ; save starting sector number
        ld      (sec),a         ; set as current sector
        restor  hl
        ld      de,10           ; offset to ^DPB
        add     hl,de
        ld      e,(hl)
        inc     hl
        ld      d,(hl)          ; DE := ^DPB
        save    de
        restor  ix              ; IX := ^DPB
        add     a,(ix+SPT)
        dec     a
        ld      (esec),a        ; esec := ssec + SPT - 1
        ld      a,(ix+OSS)
        ld      (count),a
        ld      hl,0
        ld      (track),hl
        ret




bmpdsk: ; Bump disk parameters (sector, possibly track)
        ;
        ld      a,(sec)
        inc     a
        ld      hl,esec
        cp      a,(hl)
        br      le,bdsk0        ; if (sec := sec + 1) > esec then
        ld      a,(ssec)        ;    sec := ssec
        ld      hl,(track)
        inc     hl              ;    track := track + 1
        ld      (track),hl
bdsk0:  ld      (sec),a
        ret




bmpdma: ; (dmaadr) := (dmaadr) + 128
        ;
        ld      hl,(dmaadr)
        ld      de,128
        add     hl,de
        ld      (dmaadr),hl     ; dmaadr := dmaadr + 128
        ret




select: ; Select disk directly thru cbios
        ;
        ; Entry:   (drive) = drive to select
        ; Exit:    nil
        ;
        ld      e,0             ; forces initialization
        cbios   BOSSEL,(drive)
        ret




setdma: ; Set DMA adr directly thru cbios
        ;
        ; Entry:   (dmaadr) = desired dma adr
        ; Exit:    nil
        ;
        ld      bc,(dmaadr)
        cbios   BOSDMA
        ret




settrk: ; Set track adr directly thru cbios
        ;
        ; Entry:   (track) = desired track adr
        ; Exit:    nil
        ;
        cbios   BOSTRK,(track)
        ret




setsec: ; Set sector adr directly thru cbios
        ;
        ; Entry:   (sec) = desired sector adr
        ; Exit:    nil
        ;
        cbios   BOSSEC,(sec)
        ret




getch:  ; Get a character from the console, convert to UC alfa
        ;
        ; Exit:    A = character
        ;
        charin
        cp      a,'a'
        ret     lt
        cp      a,'z'
        ret     gt
        sub     a,'a'-'A'
        ret




getdrv: ; Input drive number from console
        ;
        ; Entry:   nil
        ; Exit:    CY = 1 => CR entered
        ;          otherwise A = binary drive code.
        ;
        call    getch
        cp      a,CR
        scf
        ret     eq
        sub     a,'A'
        clrcf
        ret




dskerr: ; Process disk error condition
        ;
        ; Entry:   nil
        ; Exit:    CY = 1 if user wants to abort
        ;
        print   BEL,CR,LF,'Disk error, type RETURN to ignore '
        call    getdrv
        ccf
        ret




prndrv: ; Print drive code at console
        ;
        ; Entry:   (drive) = binary drive number
        ; Exit:    nil
        ;
        ld      a,(drive)
        add     a,'A'
        chrout
        ret




;########################################################;
;#                 SYSTEM DATA AREA                     #;
;########################################################;


ssec:   defs    1               ; starting sector adr
esec:   defs    1               ; ending sector adr
drive:  defs    1               ; current drive adr
track:  defs    2               ; current track adr
sec:    defs    1               ; current sector adr
dmaadr: defs    2               ; current dma adr
count:  defs    1               ; count of system sectors


        defs    32*2
stktop  equ     $


        end     start